|
 |
I thought that looked wrong somehow, see it correctly now.
The lathe is great though, it's more the problem with getting a
turbulent look with media that makes it difficult to use. This is a
classic example of how well a turbulence for objects themselves would be
of good use.
Well, I actually meant to add that script in with my uploaded image,
slipped my mind, as I hastily ran through all these posts and replies at
n.p.o.
So I was thinking of emailing it to you, signed off before writing the
email. Now I can get it put here (watch out for line wrap) and you'll
see just how sloppy my pov making can be.
//BEGIN
global_settings {
max_trace_level 10
}
camera {location<0,0,-9> look_at y*2.5}
//sphere {0,1 pigment {rgb 1}} //measuring stick used to judge size
//ground
plane {y,.125 pigment {rgb<.8,.7,.5>} finish {ambient .3 diffuse .7
phong .5 phong_size 1} rotate -3*x}
// evening
sky_sphere { //0,1 hollow //if sphere instead
pigment {
gradient y
color_map { [0.0 color rgb<0.9,0.5,0.475>] [1.0 color
rgb<0.2,0.45,0.65>] }
} //finish {ambient .75 diffuse .25} //if sphere
//scale 100 //if sphere
}
#declare Shroom =
lathe{
quadratic_spline
40,
<0.0000,0.0000>,<0.7501,0.0000>,<0.7500,0.0000>,<0.7908,0.0102>,
<0.8266,0.0408>,<0.8266,0.0918>,<0.7960,0.1530>,<0.7448,0.1938>,
<0.6734,0.1938>,<0.5868,0.1734>,<0.4846,0.1836>,<0.4286,0.1734>,
<0.4030,0.1326>,<0.3520,0.1020>,<0.2756,0.0816>,<0.2244,0.1122>,
<0.1990,0.1734>,<0.1480,0.2756>,<0.1276,0.4286>,<0.1122,0.6836>,
<0.0920,1.0000>,<0.0920,1.1836>,<0.0970,1.2654>,<0.1224,1.1530>,
<0.1428,1.1224>,<0.1990,1.0714>,<0.2756,1.0408>,<0.3776,1.0612>,
<0.4488,1.1020>,<0.5154,1.2040>,<0.5460,1.3674>,<0.5106,1.5200>,
<0.4494,1.5716>,<0.3780,1.6024>,<0.3522,1.6134>,<0.3060,1.6236>,
<0.2644,1.6340>,<0.1480,1.6444>,<0.0714,1.6546>,<0.0102,1.6656>
sturm hollow }
#declare DD=.125 //emission and absorption multiplier
#declare D=3 //densities multiplier
//the blast cloud
#declare Nuke =
union {
object { Shroom pigment{rgbf 1} //capable of shadow
interior {
media {
absorption <.4,.5,.6>*.75*DD
emission rgb <.6,.5,.4>*.33*DD
scattering { 2, rgb <1,.9,.8>*.125*DD extinction .1 }
density { spherical frequency 4 color_map { [.1 rgb
<.5,.35,.25>*2*D][.5 rgb <1,1,1>*2*D] }
scale 1
warp { turbulence .6 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate 3*y
} // end of density
density { cylindrical frequency 2 color_map { [.3 rgb
<1.5,1.25,1.25>*3*D][.6 rgb <.15,.1,.125>*6*D] }
scale .15
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y //translate 2*z
} // end of density
density { gradient y frequency -2 color_map { [.3 rgb
<1.25,1.25,1.5>*.5*D][.6 rgb <.125,.1,.15>*1.5*D] }
scale 3
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate -3*y
} // end of density
intervals 6
samples 1, 1
variance 0.1
confidence 0.9
} // end of media
media {
absorption <.4,.5,.6>*1*DD
//emission rgb <.6,.5,.4>*.25*DD
//scattering { 2, rgb <1,.9,.8>*.125*DD extinction .1 }
density { spherical frequency -4 color_map { [.1 rgb
<.5,.35,.25>*2*D][.5 rgb <1,1,1>*2*D] }
scale .1
warp { turbulence .6 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate 3*y
} // end of density
density { cylindrical frequency -2 color_map { [.3 rgb
<1.5,1.25,1.25>*3*D][.6 rgb <.15,.1,.125>*6*D] }
scale .015
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y //translate 2*z
} // end of density
density { gradient y frequency 2 color_map { [.3 rgb
<1.25,1.25,1.5>*.5*D][.6 rgb <.125,.1,.15>*1.5*D] }
scale .3
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate -3*y
} // end of density
intervals 3
samples 1, 1
variance 0.1
confidence 0.9
} // end of media
} // end of interior
scale 3
// rotate y*120
} // end of object
/*
#declare DD2=.25 //emission and absorption multiplier
#declare D2=2.25 //densities multiplier
//interior //not used
object { Shroom pigment{rgbt 1}
interior {
media {
absorption <.3,.5,.7>*.75*DD2
emission rgb <.7,.55,.45>*.25*DD2
scattering { 3, rgb <1,.9,.8>*.125*DD2 extinction .2 }
density { spherical frequency 4 color_map { [.1 rgb
<.5,.5,.5>*2*D2][.5 rgb <1,1,1>*2*D2] }
scale 1
warp { turbulence .6 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate 3*y
} // end of density
density { cylindrical frequency 2 color_map { [.3 rgb
<1.5,1.5,1.5>*3*D2][.6 rgb <.1,.1,.1>*6*D2] }
scale .15
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y //translate 2*z
} // end of density
density { gradient y frequency -2 color_map { [.3 rgb
<1.5,1.5,1.5>*.5*D2][.6 rgb <.1,.1,.1>*1.5*D2] }
scale 3
warp { turbulence .9 lambda 2 omega 1.0 octaves 4 }
rotate 0*-y translate -3*y
} // end of density
intervals 2
samples 1, 4
variance 0.01
confidence 0.9
} // end of media
fade_distance 2 fade_power 1
} // end of interior
scale <2.9,2.9,2.9>
// rotate y*120
} // end of object
*/
//internal light
light_source {<0,4,0> color rgb <1.5,1.45,1.4>*.66
area_light <3,0,0>,<0,0,3>,3,3 jitter adaptive 0
fade_distance 4 fade_power 2
media_attenuation on
}
light_source {<0,5,0> color rgb <1.5,1.25,1.2>*.5
//area_light <3,0,0>,<0,0,3>,3,3 jitter adaptive 0
spotlight point_at 0 radius 15 falloff 30 tightness 1
fade_distance 3 fade_power 3
media_attenuation on
}
//air cloud
torus {4,1 hollow scale <1,.25,1>
texture {
pigment {spherical frequency 2.9 //rgbt 1}}
color_map {
[0 color rgbf 1]
[.4 color rgbf <1.1,1,1,.7>]
[.7 color rgbf <1.05,1,1,.4>]
[1 color rgbf <1,1,1,.9>]
} scale 5.05 } finish {ambient .66 diffuse 1 phong .1 phong_size 10}
}
translate 5*y
}
//ground cloud
difference {
torus {4,.5 hollow scale <1,.75,1>}
torus {4,.5 scale <.9,1,.9> translate .25*y}
texture {
pigment {spherical frequency 2.9 turbulence .1 lambda 2 omega 1 //rgbt
1}}
color_map {
[0 color rgbf 1]
[.4 color rgbf <1,.9,.95,.8>]
[.7 color rgbf <1,.925,.9,.6>]
[1 color rgbf <1,1,1,1>]
} scale 5.05 } finish {ambient .75 diffuse 1}
}
scale <.95,.33,.95> rotate -3*x translate .125*y
}
//shockwave
difference {
torus {4,.5 hollow scale <1,.75,1>}
torus {4,.5 scale <.9,1,.9> translate .25*y}
texture {
pigment {spherical frequency 2.9 turbulence .02 lambda 1.75 omega 1.5
//rgbt 1}}
color_map {
[0 color rgbf 1]
[.6 color rgbf <1,.925,.95,.85>]
[.7 color rgbf <1,.95,.975,.65>]
[1 color rgbf <1,1,1,.95>]
} scale 5.05 } finish {ambient .75 diffuse 1}
}
interior {ior 1.01}
scale <.95,.125,.95>*1.75 rotate -3*x translate .125*y
}
} //end union
Nuke //the main blast cloud
//END
--
omniVERSE: beyond the universe
http://members.aol.com/inversez/homepage.htm
mailto:inv### [at] aol com?Subject=PoV-News
Post a reply to this message
|
|
